=pod

=head1 NAME

README - Turbo Vision inspired TUI framework for Perl

=head1 SYNOPSIS

  package MyApp;

  use Moo;
  use TUI::Objects;
  use TUI::Drivers;
  use TUI::App;
  use TUI::Menus;
  use TUI::Dialogs;
  use TUI::Views;

  extends TApplication;

  use constant {
    cmAbout => 1001,
  };

  sub initMenuBar {
    my ( $class, $r ) = @_;
    $r->{b}{y} = $r->{a}{y} + 1;
    return TMenuBar->new(
      bounds => $r,
      menu   => new_TSubMenu('~A~pp', kbAltA)
                + new_TMenuItem('~A~bout...', cmAbout, kbNoKey)
                + newLine()
                + new_TMenuItem('E~x~it', cmQuit, kbAltX)
    );
  }

  sub handleEvent {
    my ( $self, $event ) = @_;
    $self->SUPER::handleEvent($event);
    return unless $event->{what} == evCommand;
    return unless $event->{message}{command} == cmAbout;

    my $dialog = TDialog->new(
      bounds => TRect->new( ax => 20, ay => 6, bx => 60, by => 15 ),
      title  => 'About'
    );
    $dialog->insert(
      TStaticText->new(
        bounds => TRect->new( ax => 3, ay => 3, bx => 35, by => 5 ),
        text   => "\003Hello from TUI::Vision"
      )
    );
    $dialog->insert(
      TButton->new(
        bounds  => TRect->new( ax => 14, ay => 6, bx => 26, by => 8 ),
        title   => '~O~K',
        command => cmOK,
        flags   => bfDefault
      )
    );

    $deskTop->execView($dialog);
    $self->destroy($dialog);
    $self->clearEvent($event);
    return;
  }

  package main;
  my $app = MyApp->new();
  $app->run();

=head1 DESCRIPTION

L<TUI::Vision> provides a Perl port of the classic I<Turbo Vision> framework.
It is designed as a modular and portable text user interface (TUI) framework 
for Perl applications, based on I<Turbo Vision> 2.0.

The framework is a clean and native Perl implementation, adapted for 
contemporary Perl environments while preserving the original architectural 
concepts.

The goal of L<TUI::Vision> is to provide a complete and extensible TUI
framework. All modules included in this release are under active development. 
Additional functionality will be delivered incrementally in future versions.

The following framework modules and namespace entry points are included in the 
distribution:

=over 4

=item * Core object system (L<Objects|TUI::Objects>)

=item * View and windowing system (L<Views|TUI::Views>)

=item * L<Dialogs|TUI::Dialogs> and controls

=item * L<Menus|TUI::Menus> and status lines

=item * Application framework: L<App|TUI::App>

=item * L<Drivers|TUI::Drivers> and hardware abstraction

=item * L<Gadgets|TUI::Gadgets> and diagnostic tools

=item * Standard dialogs (L<StdDlg|TUI::StdDlg>)

=item * Message boxes (L<MsgBox|TUI::MsgBox>)

=item * Text rendering subsystem (L<TextView|TUI::TextView>)

=item * Color selection components (L<ColorSel|TUI::ColorSel>)

=item * Editor components (L<Editors|TUI::Editors>)

=item * Outline components (L<Outline|TUI::Outline>)

=item * Help system (L<Help|TUI::Help>)

=item * Turbo Vision Demo gadgets (L<Gadgets|TUI::Gadgets>)

=item * L<Memory|TUI::Memory> utilities

=item * Validation utilities (L<Validate|TUI::Validate>)

=item * Unified OO L<toolkit|TUI::toolkit>

=back

=head1 STATUS

This distribution is under active development.

The Perl port implements most of the core 
L<Turbo Vision subsystems|TUI::Manual::Reference::Porting>. Some legacy
resource classes are intentionally not ported because they are not required by
the current storage architecture. Implementation status does not imply complete
behavioral parity with the original C++ implementation.

=head1 AUTHORS

=over

=item * Turbo Vision Development Team

=item * J. Schneider <brickpool@cpan.org> (Perl implementation and maintenance)

=back

=head1 CONTRIBUTORS

Contributors are documented in the POD of the respective framework modules.

=head1 COPYRIGHT AND LICENSE

Copyright (c) 1990-1994, 1997 by Borland International

Copyright (c) 2021-2026 the L</AUTHORS> as listed above.

This software is licensed under the MIT license (see the LICENSE file, which is 
part of the distribution).

=cut
